From 80942f7eb331b6b975be7a2d3e9bec8acdc941f3 Mon Sep 17 00:00:00 2001
From: Antoine Martin <antoine97.martin@gmail.com>
Date: Mon, 22 Feb 2021 18:59:37 +0100
Subject: [PATCH] wireguard: setup VPN

---
 .gitattributes             |   1 +
 base/default.nix           |   1 +
 base/networking.nix        |  12 ++++
 hosts/poseidon/default.nix |  18 ++++++
 secrets/default.nix        |   4 +-
 secrets/wireguard.nix      | Bin 0 -> 377 bytes
 services/default.nix       |   1 +
 services/wireguard.nix     | 122 +++++++++++++++++++++++++++++++++++++
 8 files changed, 158 insertions(+), 1 deletion(-)
 create mode 100644 base/networking.nix
 create mode 100644 secrets/wireguard.nix
 create mode 100644 services/wireguard.nix

diff --git a/.gitattributes b/.gitattributes
index ca9c5d8..0fe79d9 100644
--- a/.gitattributes
+++ b/.gitattributes
@@ -1 +1,2 @@
 secrets/*.secret filter=git-crypt diff=git-crypt
+secrets/wireguard.nix filter=git-crypt diff=git-crypt
diff --git a/base/default.nix b/base/default.nix
index 35ec4f2..03d0b3d 100644
--- a/base/default.nix
+++ b/base/default.nix
@@ -1,6 +1,7 @@
 { ... }:
 {
   imports = [
+    ./networking.nix
     ./nix.nix
     ./users.nix
   ];
diff --git a/base/networking.nix b/base/networking.nix
new file mode 100644
index 0000000..c17ed76
--- /dev/null
+++ b/base/networking.nix
@@ -0,0 +1,12 @@
+{ lib, ... }:
+{
+  options.my.networking.externalInterface = with lib; mkOption {
+    type = types.nullOr types.str;
+    default = null;
+    example = "eth0";
+    description = ''
+      Name of the network interface that egresses to the internet. Used for
+      e.g. NATing internal networks.
+    '';
+  };
+}
diff --git a/hosts/poseidon/default.nix b/hosts/poseidon/default.nix
index d5ec7c7..1ff88f2 100644
--- a/hosts/poseidon/default.nix
+++ b/hosts/poseidon/default.nix
@@ -41,6 +41,7 @@ in
     "62.210.16.6"
     "62.210.16.7"
   ];
+  my.networking.externalInterface = "eno1";
 
   # List packages installed in system profile. To search, run:
   # $ nix search wget
@@ -119,6 +120,23 @@ in
       username = "alarsyo";
       password = secrets.transmission-password;
     };
+
+    wireguard = {
+      enable = true;
+      iface = "wg";
+      port = 51820;
+
+      net = {
+        v4 = {
+          subnet = "10.0.0";
+          mask = 24;
+        };
+        v6 = {
+          subnet = "fd42:42:42";
+          mask = 64;
+        };
+      };
+    };
   };
 
   security.acme.acceptTerms = true;
diff --git a/secrets/default.nix b/secrets/default.nix
index 19bd7d6..7d0e393 100644
--- a/secrets/default.nix
+++ b/secrets/default.nix
@@ -1,4 +1,4 @@
-{ lib, config, ... }:
+{ pkgs, lib, config, ... }:
 with lib;
 {
   options.my.secrets = mkOption {
@@ -12,5 +12,7 @@ with lib;
     miniflux-admin-credentials = lib.fileContents ./miniflux-admin-credentials.secret;
     borg-backup-repo = lib.fileContents ./borg-backup-repo.secret;
     transmission-password = lib.fileContents ./transmission.secret;
+
+    wireguard = pkgs.callPackage ./wireguard.nix { };
   };
 }
diff --git a/secrets/wireguard.nix b/secrets/wireguard.nix
new file mode 100644
index 0000000000000000000000000000000000000000..e2bed7964ad51f1b653c57785e7468455aad3a78
GIT binary patch
literal 377
zcmV-<0fznnM@dveQdv+`0DK+d{uV>~6PsL=#VK5MFIh(1dHLCe2d1yC26kegnTWlg
zv<5$JMVzoo?Kxi0?hMzbm77M1HO%P<Y#10|bO3&N0k7yfMXy0^ict@HBA@u1m7B(b
zRkayo56W8&*OXv56W*znM&dA+<=(Y%x)VsN<tvl~YfBYS^Nu!6?QR)wY2<rJj1EvZ
zEcXzV<RC{^oN$@E?q8msuu)H8M+#j&i6}_yx5Sd|nxCrSm=Ep#VsJ)Bt~d#V1jzLq
zh=v%<ez->hJm`5(dEtqDJLf+6MtA<4GjVJmkS?~46FW@LcL5j{^bq2T<HUL$7Sqt6
zt)VD7I=kA|mAt||FUg?pX+)Pr^|GUn9PE5T=R-D6YOsLCUV4x30XIh#g9PV5Y+MWN
zi}tTkS`p++Wo%HNC@_+<n|dL%!F~DqPb}cmUtw^F5x{;O27<>_{ZW=F%Ee)pW3F2d
Xb7I>sKW@Bv4iF7IV)<Y`(2ZRN+0wC5

literal 0
HcmV?d00001

diff --git a/services/default.nix b/services/default.nix
index 707a116..07c86fa 100644
--- a/services/default.nix
+++ b/services/default.nix
@@ -14,5 +14,6 @@
     ./nginx.nix
     ./postgresql-backup.nix
     ./transmission.nix
+    ./wireguard.nix
   ];
 }
diff --git a/services/wireguard.nix b/services/wireguard.nix
new file mode 100644
index 0000000..9d13b55
--- /dev/null
+++ b/services/wireguard.nix
@@ -0,0 +1,122 @@
+# Stolen from:
+#
+# https://gitea.belanyi.fr/ambroisie/nix-config/src/branch/main/services/wireguard.nix
+
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.my.services.wireguard;
+  hostName = config.networking.hostName;
+
+  peers = config.my.secrets.wireguard.peers;
+  thisPeer = peers."${hostName}";
+  otherPeers = lib.filterAttrs (name: _: name != hostName) peers;
+
+  extIface = config.my.networking.externalInterface;
+in
+{
+  options.my.services.wireguard = with lib; {
+    enable = mkEnableOption "Wireguard VPN service";
+
+    iface = mkOption {
+      type = types.str;
+      default = "wg";
+      example = "wg0";
+      description = "Name of the interface to configure";
+    };
+
+    port = mkOption {
+      type = types.port;
+      default = 51820;
+      example = 55555;
+      description = "Port to configure for Wireguard";
+    };
+
+    net = {
+      v4 = {
+        subnet = mkOption {
+          type = types.str;
+          default = "10.0.0";
+          example = "10.100.0";
+          description = "Which prefix to use for internal IPs";
+        };
+        mask = mkOption {
+          type = types.int;
+          default = 24;
+          example = 28;
+          description = "The CIDR mask to use on internal IPs";
+        };
+      };
+      v6 = {
+        subnet = mkOption {
+          type = types.str;
+          default = "fd42:42:42";
+          example = "fdc9:281f:04d7:9ee9";
+          description = "Which prefix to use for internal IPs";
+        };
+        mask = mkOption {
+          type = types.int;
+          default = 64;
+          example = 68;
+          description = "The CIDR mask to use on internal IPs";
+        };
+      };
+    };
+  };
+
+  config.networking = lib.mkIf cfg.enable {
+    wg-quick.interfaces."${cfg.iface}" = {
+      listenPort = cfg.port;
+      address = with cfg.net; with lib; [
+        "${v4.subnet}.${toString thisPeer.clientNum}/${toString v4.mask}"
+        "${v6.subnet}::${toString thisPeer.clientNum}/${toHexString v6.mask}"
+      ];
+      privateKey = thisPeer.privateKey;
+
+      peers = lib.mapAttrsToList
+        (name: peer: {
+          inherit (peer) publicKey;
+        } // lib.optionalAttrs (thisPeer ? externalIp) {
+          # Only forward from server to clients
+          allowedIPs = with cfg.net; [
+            "${v4.subnet}.${toString peer.clientNum}/32"
+            "${v6.subnet}::${toString peer.clientNum}/128"
+          ];
+        } // lib.optionalAttrs (peer ? externalIp) {
+          # Known addresses
+          endpoint = "${peer.externalIp}:${toString cfg.port}";
+        } // lib.optionalAttrs (!(thisPeer ? externalIp)) {
+          # Forward all traffic to server
+          allowedIPs = with cfg.net; [
+            "0.0.0.0/0"
+            "::/0"
+          ];
+          # Roaming clients need to keep NAT-ing active
+          persistentKeepalive = 10;
+        })
+        otherPeers;
+    } // lib.optionalAttrs (thisPeer ? externalIp) {
+      # Setup forwarding on server
+      postUp = with cfg.net; ''
+        ${pkgs.iptables}/bin/iptables -A FORWARD -i ${cfg.iface} -j ACCEPT
+        ${pkgs.iptables}/bin/iptables -t nat -A POSTROUTING -s ${v4.subnet}.1/${toString v4.mask} -o ${extIface} -j MASQUERADE
+        ${pkgs.iptables}/bin/ip6tables -A FORWARD -i ${cfg.iface} -j ACCEPT
+        ${pkgs.iptables}/bin/ip6tables -t nat -A POSTROUTING -s ${v6.subnet}::1/${toString v6.mask} -o ${extIface} -j MASQUERADE
+      '';
+      preDown = with cfg.net; ''
+        ${pkgs.iptables}/bin/iptables -D FORWARD -i ${cfg.iface} -j ACCEPT
+        ${pkgs.iptables}/bin/iptables -t nat -D POSTROUTING -s ${v4.subnet}.1/${toString v4.mask} -o ${extIface} -j MASQUERADE
+        ${pkgs.iptables}/bin/ip6tables -D FORWARD -i ${cfg.iface} -j ACCEPT
+        ${pkgs.iptables}/bin/ip6tables -t nat -D POSTROUTING -s ${v6.subnet}::1/${toString v6.mask} -o ${extIface} -j MASQUERADE
+      '';
+
+    };
+
+    nat = lib.optionalAttrs (thisPeer ? externalIp) {
+      enable = true;
+      externalInterface = extIface;
+      internalInterfaces = [ cfg.iface ];
+    };
+
+    firewall.allowedUDPPorts = lib.optional (thisPeer ? externalIp) cfg.port;
+  };
+}