From a763e0549f4a8db7f03c591833c2745aae840013 Mon Sep 17 00:00:00 2001
From: Antoine Martin <antoine@alarsyo.net>
Date: Mon, 9 Aug 2021 19:34:23 +0200
Subject: [PATCH] services: setup restic backups service

---
 hosts/poseidon/default.nix                 |   4 +-
 secrets/default.nix                        |   1 +
 secrets/restic-backup/default.nix          |   4 +
 secrets/restic-backup/poseidon-repo.secret | Bin 0 -> 41 bytes
 services/default.nix                       |   1 +
 services/restic-backup.nix                 |  83 +++++++++++++++++++++
 6 files changed, 91 insertions(+), 2 deletions(-)
 create mode 100644 secrets/restic-backup/default.nix
 create mode 100644 secrets/restic-backup/poseidon-repo.secret
 create mode 100644 services/restic-backup.nix

diff --git a/hosts/poseidon/default.nix b/hosts/poseidon/default.nix
index e45b02a..46840ba 100644
--- a/hosts/poseidon/default.nix
+++ b/hosts/poseidon/default.nix
@@ -66,9 +66,9 @@ in
       websocketPort = 3012;
     };
 
-    borg-backup = {
+    restic-backup = {
       enable = true;
-      repo = secrets.borg-backup.poseidon-repo;
+      repo = secrets.restic-backup.poseidon-repo;
     };
 
     fail2ban = {
diff --git a/secrets/default.nix b/secrets/default.nix
index 547eb06..59c9049 100644
--- a/secrets/default.nix
+++ b/secrets/default.nix
@@ -17,6 +17,7 @@ with lib;
     gandiKey = lib.fileContents ./gandi-api-key.secret;
 
     borg-backup = import ./borg-backup { inherit lib; };
+    restic-backup = import ./restic-backup { inherit lib; };
 
     matrixEmailConfig = import ./matrix-email-config.nix;
   };
diff --git a/secrets/restic-backup/default.nix b/secrets/restic-backup/default.nix
new file mode 100644
index 0000000..1d6b630
--- /dev/null
+++ b/secrets/restic-backup/default.nix
@@ -0,0 +1,4 @@
+{ lib }:
+{
+  poseidon-repo = lib.fileContents ./poseidon-repo.secret;
+}
diff --git a/secrets/restic-backup/poseidon-repo.secret b/secrets/restic-backup/poseidon-repo.secret
new file mode 100644
index 0000000000000000000000000000000000000000..db082cf2c1ff6419a2e6c357dc10e42f7f8b7d38
GIT binary patch
literal 41
xcmZQ@_Y83kiVO&0XiwF?^k1TW<5}l(-m<>pw|%|azb^YAsr!DnJ<s(o#sE-*5)S|X

literal 0
HcmV?d00001

diff --git a/services/default.nix b/services/default.nix
index 2904314..4291e78 100644
--- a/services/default.nix
+++ b/services/default.nix
@@ -20,6 +20,7 @@
     ./pipewire.nix
     ./postgresql-backup.nix
     ./postgresql.nix
+    ./restic-backup.nix
     ./tailscale.nix
     ./tgv.nix
     ./transmission.nix
diff --git a/services/restic-backup.nix b/services/restic-backup.nix
new file mode 100644
index 0000000..701cd97
--- /dev/null
+++ b/services/restic-backup.nix
@@ -0,0 +1,83 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.my.services.restic-backup;
+  secrets = config.my.secrets;
+  excludeArg = with builtins; with pkgs;
+    "--exclude-file=" + (writeText "excludes.txt" (concatStringsSep "\n" cfg.exclude));
+  makePruneOpts = pruneOpts:
+    attrsets.mapAttrsToList (name: value: "--keep-${name} ${toString value}") pruneOpts;
+in {
+  options.my.services.restic-backup = {
+    enable = mkEnableOption "Enable Restic backups for this host";
+
+    repo = mkOption {
+      type = types.str;
+      default = null;
+      example = "/mnt/hdd";
+      description = "Restic backup repo";
+
+    };
+
+    paths = mkOption {
+      type = with types; listOf str;
+      default = [ ];
+      example = [
+        "/var/lib"
+        "/home"
+      ];
+      description = "Paths to backup";
+    };
+
+    exclude = mkOption {
+      type = with types; listOf str;
+      default = [ ];
+      example = [
+        # very large paths
+        "/var/lib/docker"
+        "/var/lib/systemd"
+        "/var/lib/libvirt"
+
+        # temporary files created by `cargo` and `go build`
+        "**/target"
+        "/home/*/go/bin"
+        "/home/*/go/pkg"
+      ];
+      description = "Paths to exclude from backup";
+    };
+
+    prune = mkOption {
+      type = types.attrs;
+      default = {
+        daily = 7;
+        weekly = 4;
+        monthly = 6;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    environment.systemPackages = [ pkgs.restic ];
+
+    services.restic.backups.backblaze = {
+      initialize = true;
+
+      paths = cfg.paths;
+
+      repository = cfg.repo;
+      passwordFile = "/root/restic/password";
+      s3CredentialsFile = "/root/restic/creds";
+
+      extraBackupArgs = [ ]
+        ++ optional (builtins.length cfg.exclude != 0) excludeArg;
+
+      timerConfig = {
+        OnCalendar = "daily";
+      };
+
+      pruneOpts = makePruneOpts cfg.prune;
+    };
+  };
+}