services: setup prololo test service

hosts/poseidon/default.nix

@@ -134,6 +134,19 @@ in
       enable = true;
     };
 
+    prololo = {
+      enable = true;
+      port = 8089;
+      settings = {
+        matrix_username = "prololo";
+        matrix_password = config.my.secrets.prololo_password;
+        matrix_homeserver = "https://matrix.alarsyo.net";
+        matrix_room_id = config.my.secrets.prololo_room;
+        matrix_state_dir = "./prololo_state_dir";
+        github_secret = config.my.secrets.prololo_github_secret;
+      };
+    };
+
     tailscale = {
       enable = true;
       exitNode = true;

secrets/default.nix

@@ -20,5 +20,9 @@ with lib;
     restic-backup = import ./restic-backup { inherit lib; };
 
     matrixEmailConfig = import ./matrix-email-config.nix;
+
+    prololo_password = lib.fileContents ./prololo-password.secret;
+    prololo_room = lib.fileContents ./prololo-room.secret;
+    prololo_github_secret = lib.fileContents ./prololo-github-secret.secret;
   };
 }

services/default.nix

@@ -21,6 +21,7 @@
     ./pipewire.nix
     ./postgresql-backup.nix
     ./postgresql.nix
+    ./prololo.nix
     ./restic-backup.nix
     ./tailscale.nix
     ./tgv.nix

services/prololo.nix

@@ -0,0 +1,80 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.my.services.prololo;
+  my = config.my;
+  domain = config.networking.domain;
+  prololoPkg =
+    let
+      flake = builtins.getFlake "github:alarsyo/prololo-reborn?rev=40da010f5782bc760c83ac9883716970fcee40ff";
+    in
+      flake.defaultPackage."x86_64-linux"; # FIXME: use correct system
+  settingsFormat = pkgs.formats.yaml {};
+in
+{
+  options.my.services.prololo = {
+    enable = lib.mkEnableOption "Prololo Matrix bot";
+
+    home = mkOption {
+      type = types.str;
+      default = "/var/lib/prololo";
+      example = "/var/lib/prololo";
+      description = "Home for the prololo service, where data will be stored";
+    };
+
+    port = mkOption {
+      type = types.port;
+      default = 8080;
+      example = 8080;
+      description = "Internal port for Prololo Rocket server";
+    };
+
+    settings = mkOption {
+      type = settingsFormat.type;
+      default = {};
+    };
+  };
+
+  config =
+    let
+      configFile = settingsFormat.generate "config.yaml" cfg.settings;
+    in mkIf cfg.enable
+      {
+        systemd.services.prololo = {
+          wantedBy = [ "multi-user.target" ];
+          serviceConfig = {
+            Environment = [
+              "ROCKET_PORT=${toString cfg.port}"
+              "ROCKET_LOG_LEVEL=normal"
+              "RUST_LOG=rocket=info,prololo_reborn=trace"
+            ];
+            ExecStart = "${prololoPkg}/bin/prololo-reborn --config ${configFile}";
+            StateDirectory = "prololo";
+            WorkingDirectory = cfg.home;
+            User = "prololo";
+            Group = "prololo";
+          };
+        };
+
+        users.users.prololo = {
+          isSystemUser = true;
+          home = cfg.home;
+          createHome = true;
+          group = "prololo";
+        };
+        users.groups.prololo = { };
+
+        services.nginx.virtualHosts = {
+          "prololo.${domain}" = {
+            forceSSL = true;
+            useACMEHost = domain;
+
+            locations."/" = {
+              proxyPass = "http://127.0.0.1:${toString cfg.port}";
+            };
+          };
+        };
+      };
+}