* HACKING, Makefile.am, configure.ac, m4/gccwarn.m4,

src/Makefile.am, src/ltlast/Makefile.am, src/ltlast/allnodes.hh,
src/ltlast/atomic_prop.cc, src/ltlast/atomic_prop.hh,
src/ltlast/binop.cc, src/ltlast/binop.hh, src/ltlast/constant.cc,
src/ltlast/constant.hh, src/ltlast/formulae.hh,
src/ltlast/multop.cc, src/ltlast/multop.hh, src/ltlast/predecl.hh,
src/ltlast/unop.cc, src/ltlast/unop.hh, src/ltlast/visitor.hh,
src/ltlparse/Makefile.am, src/ltlparse/ltlparse.yy,
src/ltlparse/ltlscan.ll, src/ltlparse/parsedecl.hh,
src/ltlparse/public.hh, src/ltlvisit/Makefile.am,
src/ltlvisit/dotty.cc, src/ltlvisit/dotty.hh,
src/ltlvisit/dump.cc, src/ltlvisit/dump.hh,
src/ltlvisit/rewrite.cc, src/ltlvisit/rewrite.hh,
src/ltltest/Makefile.am, src/ltltest/defs.in, src/ltltest/readltl.cc,
src/ltltest/parse.test, src/ltltest/parseerr.test,
src/misc/Makefile.am, src/misc/const_sel.hh: New files.

m4/gccwarn.m4

@@ -0,0 +1,46 @@
+dnl Check if the compiler supports useful warning options.  There's a few that
+dnl we don't use, simply because they're too noisy:
+dnl
+dnl -ansi (prevents declaration of functions like strdup, and because
+dnl        it makes warning in system headers).
+dnl -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
+dnl -Wtraditional (combines too many unrelated messages, only a few useful)
+dnl -Wredundant-decls (system headers make this too noisy)
+dnl -pedantic
+dnl -Wunreachable-code (broken, see GCC PR/7827)
+dnl -Wredundant-decls (too many warnings in GLIBC's header with old GCC)
+dnl
+dnl A few other options have been left out because they are annoying in C++.
+
+
+AC_DEFUN([CF_GXX_WARNINGS],
+[if test -n "$GXX"; then
+  AC_CACHE_CHECK([for g++ warning options], ac_cv_prog_gxx_warn_flags,
+  [
+  cat > conftest.$ac_ext <<EOF
+#line __oline__ "configure"
+int main(int argc, char *argv[[]]) { return argv[[argc-1]] == 0; }
+EOF
+  cf_save_CXXFLAGS="$CXXFLAGS"
+  ac_cv_prog_gxx_warn_flags="-W -Wall"
+  for cf_opt in \
+   Wcast-align \
+   Winline \
+   Wpointer-arith \
+   Wwrite-strings \
+   Wstrict-prototypes \
+   Wcast-qual \
+   Werror
+  do
+    CXXFLAGS="$cf_save_CXXFLAGS $ac_cv_prog_gxx_warn_flags -$cf_opt"
+    if AC_TRY_EVAL(ac_compile); then
+      ac_cv_prog_gxx_warn_flags="$ac_cv_prog_gxx_warn_flags -$cf_opt"
+      test "$cf_opt" = Wcast-qual && ac_cv_prog_gxx_warn_flags="$ac_cv_prog_gxx_warn_flags -DXTSTRINGDEFINES"
+    fi
+  done
+  rm -f conftest*
+  CXXFLAGS="$cf_save_CXXFLAGS"])
+fi
+AC_SUBST([WARNING_CXXFLAGS], ["${ac_cv_prog_gxx_warn_flags}"])
+])
+