2076197e8d
* lib/Makefile.am, lib/alloca.in.h, lib/arg-nonnull.h, lib/argmatch.c, lib/argmatch.h, lib/argp-ba.c, lib/argp-eexst.c, lib/argp-fmtstream.c, lib/argp-fmtstream.h, lib/argp-fs-xinl.c, lib/argp-help.c, lib/argp-namefrob.h, lib/argp-parse.c, lib/argp-pin.c, lib/argp-pv.c, lib/argp-pvh.c, lib/argp-xinl.c, lib/argp.h, lib/asnprintf.c, lib/basename-lgpl.c, lib/c++defs.h, lib/c-ctype.h, lib/c-strcase.h, lib/c-strcasecmp.c, lib/c-strcaseeq.h, lib/c-strncasecmp.c, lib/config.charset, lib/dirname-lgpl.c, lib/dirname.h, lib/dosname.h, lib/errno.in.h, lib/error.c, lib/error.h, lib/exitfail.c, lib/exitfail.h, lib/fcntl.in.h, lib/filename.h, lib/float+.h, lib/float.c, lib/float.in.h, lib/getopt-cdefs.in.h, lib/getopt-core.h, lib/getopt-ext.h, lib/getopt-pfx-core.h, lib/getopt-pfx-ext.h, lib/getopt.c, lib/getopt.in.h, lib/getopt1.c, lib/getopt_int.h, lib/getprogname.c, lib/getprogname.h, lib/gettext.h, lib/gettimeofday.c, lib/hard-locale.c, lib/hard-locale.h, lib/intprops.h, lib/isatty.c, lib/itold.c, lib/limits.in.h, lib/localcharset.c, lib/localcharset.h, lib/localtime-buffer.c, lib/localtime-buffer.h, lib/lstat.c, lib/malloc.c, lib/malloca.c, lib/malloca.h, lib/mbrtowc.c, lib/mbsinit.c, lib/memchr.c, lib/mempcpy.c, lib/minmax.h, lib/mkstemp.c, lib/mkstemps.c, lib/msvc-inval.c, lib/msvc-inval.h, lib/msvc-nothrow.c, lib/msvc-nothrow.h, lib/pathmax.h, lib/printf-args.c, lib/printf-args.h, lib/printf-parse.c, lib/printf-parse.h, lib/progname.c, lib/progname.h, lib/quote.h, lib/quotearg.c, lib/quotearg.h, lib/rawmemchr.c, lib/ref-add.sin, lib/ref-del.sin, lib/size_max.h, lib/sleep.c, lib/stat-w32.c, lib/stat-w32.h, lib/stat.c, lib/stdalign.in.h, lib/stdbool.in.h, lib/stddef.in.h, lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h, lib/stpcpy.c, lib/strcasecmp.c, lib/strchrnul.c, lib/streq.h, lib/strerror-override.c, lib/strerror-override.h, lib/strerror.c, lib/string.in.h, lib/strings.in.h, lib/stripslash.c, lib/strncasecmp.c, lib/strndup.c, lib/strnlen.c, lib/strverscmp.c, lib/sys_stat.in.h, lib/sys_time.in.h, lib/sys_types.in.h, lib/sys_wait.in.h, lib/sysexits.in.h, lib/tempname.c, lib/tempname.h, lib/time.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/vasnprintf.h, lib/verify.h, lib/vsnprintf.c, lib/warn-on-use.h, lib/wchar.in.h, lib/wctype.in.h, lib/xalloc-die.c, lib/xalloc-oversized.h, lib/xalloc.h, lib/xmalloc.c, lib/xsize.h, m4/00gnulib.m4, m4/absolute-header.m4, m4/alloca.m4, m4/argp.m4, m4/configmake.m4, m4/dirname.m4, m4/double-slash-root.m4, m4/eealloc.m4, m4/errno_h.m4, m4/error.m4, m4/exponentd.m4, m4/extensions.m4, m4/extern-inline.m4, m4/fcntl-o.m4, m4/fcntl_h.m4, m4/float_h.m4, m4/getopt.m4, m4/getprogname.m4, m4/gettimeofday.m4, m4/glibc21.m4, m4/gnulib-cache.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/gnulib-tool.m4, m4/hard-locale.m4, m4/include_next.m4, m4/intmax_t.m4, m4/inttypes_h.m4, m4/isatty.m4, m4/largefile.m4, m4/limits-h.m4, m4/localcharset.m4, m4/locale-fr.m4, m4/locale-ja.m4, m4/locale-zh.m4, m4/localtime-buffer.m4, m4/longlong.m4, m4/lstat.m4, m4/malloc.m4, m4/malloca.m4, m4/math_h.m4, m4/mbrtowc.m4, m4/mbsinit.m4, m4/mbstate_t.m4, m4/memchr.m4, m4/mempcpy.m4, m4/minmax.m4, m4/mkstemp.m4, m4/mkstemps.m4, m4/mmap-anon.m4, m4/msvc-inval.m4, m4/msvc-nothrow.m4, m4/multiarch.m4, m4/nocrash.m4, m4/off_t.m4, m4/pathmax.m4, m4/printf.m4, m4/quote.m4, m4/quotearg.m4, m4/rawmemchr.m4, m4/size_max.m4, m4/sleep.m4, m4/ssize_t.m4, m4/stat.m4, m4/stdalign.m4, m4/stdbool.m4, m4/stddef_h.m4, m4/stdint.m4, m4/stdint_h.m4, m4/stdio_h.m4, m4/stdlib_h.m4, m4/stpcpy.m4, m4/strcase.m4, m4/strchrnul.m4, m4/strerror.m4, m4/string_h.m4, m4/strings_h.m4, m4/strndup.m4, m4/strnlen.m4, m4/strverscmp.m4, m4/sys_socket_h.m4, m4/sys_stat_h.m4, m4/sys_time_h.m4, m4/sys_types_h.m4, m4/sys_wait_h.m4, m4/sysexits.m4, m4/tempname.m4, m4/time_h.m4, m4/unistd_h.m4, m4/vasnprintf.m4, m4/vsnprintf.m4, m4/warn-on-use.m4, m4/wchar_h.m4, m4/wchar_t.m4, m4/wctype_h.m4, m4/wint_t.m4, m4/xalloc.m4, m4/xsize.m4: Update. * lib/malloca.valgrind, lib/secure_getenv.c, m4/secure_getenv.m4: Delete. * lib/stat-time.c, lib/stat-time.h, m4/stat-time.m4: New files.
83 lines
3 KiB
Text
83 lines
3 KiB
Text
# Checks for stat-related time functions.
|
|
|
|
# Copyright (C) 1998-1999, 2001, 2003, 2005-2007, 2009-2018 Free Software
|
|
# Foundation, Inc.
|
|
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Paul Eggert.
|
|
|
|
# st_atim.tv_nsec - Linux, Solaris, Cygwin
|
|
# st_atimespec.tv_nsec - FreeBSD, NetBSD, if ! defined _POSIX_SOURCE
|
|
# st_atimensec - FreeBSD, NetBSD, if defined _POSIX_SOURCE
|
|
# st_atim.st__tim.tv_nsec - UnixWare (at least 2.1.2 through 7.1)
|
|
|
|
# st_birthtimespec - FreeBSD, NetBSD (hidden on OpenBSD 3.9, anyway)
|
|
# st_birthtim - Cygwin 1.7.0+
|
|
|
|
AC_DEFUN([gl_STAT_TIME],
|
|
[
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
AC_CHECK_HEADERS_ONCE([sys/time.h])
|
|
|
|
AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
|
|
[AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
|
|
[ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
|
|
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
|
|
[[
|
|
#include <sys/types.h>
|
|
#include <sys/stat.h>
|
|
#if HAVE_SYS_TIME_H
|
|
# include <sys/time.h>
|
|
#endif
|
|
#include <time.h>
|
|
struct timespec ts;
|
|
struct stat st;
|
|
]],
|
|
[[
|
|
st.st_atim = ts;
|
|
]])],
|
|
[ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
|
|
[ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
|
|
if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
|
|
AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], [1],
|
|
[Define to 1 if the type of the st_atim member of a struct stat is
|
|
struct timespec.])
|
|
fi],
|
|
[AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
|
|
[AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
|
|
[AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [], [],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])
|
|
])
|
|
|
|
# Check for st_birthtime, a feature from UFS2 (FreeBSD, NetBSD, OpenBSD, etc.)
|
|
# and NTFS (Cygwin).
|
|
# There was a time when this field was named st_createtime (21 June
|
|
# 2002 to 16 July 2002) But that window is very small and applied only
|
|
# to development code, so systems still using that configuration are
|
|
# not supported. See revisions 1.10 and 1.11 of FreeBSD's
|
|
# src/sys/ufs/ufs/dinode.h.
|
|
#
|
|
AC_DEFUN([gl_STAT_BIRTHTIME],
|
|
[
|
|
AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
|
|
AC_CHECK_HEADERS_ONCE([sys/time.h])
|
|
AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_nsec], [],
|
|
[AC_CHECK_MEMBERS([struct stat.st_birthtimensec], [],
|
|
[AC_CHECK_MEMBERS([struct stat.st_birthtim.tv_nsec], [], [],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])],
|
|
[#include <sys/types.h>
|
|
#include <sys/stat.h>])
|
|
])
|