80d50c5665
* tools/snippet/_Noreturn.h, tools/snippet/c++defs.h, tools/snippet/arg-nonnull.h, tools/snippet/warn-on-use.h: Rename to... * lib/_Noreturn.h, lib/c++defs.h, lib/arg-nonnull.h, lib/warn-on-use.h: ... these. * lib/filename.h, lib/getopt-cdefs.in.h, lib/getopt-core.h, lib/getopt-ext.h, lib/getopt-pfx-core.h, lib/getopt-pfx-ext.h, lib/localtime-buffer.c, lib/localtime-buffer.h, lib/malloca.c, lib/malloca.h, lib/malloca.valgrind, lib/stat-w32.c, lib/stat-w32.h, m4/eealloc.m4, m4/localtime-buffer.m4, m4/malloca.m4: New files. * lib/argp-help.c, lib/argp-parse.c, lib/error.c, lib/float.in.h, lib/getopt1.c, lib/getopt.c, lib/getopt.in.h, lib/getopt_int.h, lib/gettext.h, lib/gettimeofday.c, lib/intprops.h, lib/isatty.c, lib/limits.in.h, lib/localcharset.c, lib/Makefile.am, lib/mbrtowc.c, lib/mbsinit.c, lib/msvc-nothrow.c, lib/quotearg.c, lib/stat.c, lib/stdalign.in.h, lib/stdint.in.h, lib/string.in.h, lib/sys_stat.in.h, lib/sys_types.in.h, lib/tempname.c, lib/time.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/wchar.in.h, lib/wctype.in.h, lib/xalloc.h, lib/xalloc-oversized.h, m4/fcntl-o.m4, m4/float_h.m4, m4/getopt.m4, m4/gettimeofday.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/include_next.m4, m4/largefile.m4, m4/lstat.m4, m4/mbrtowc.m4, m4/memchr.m4, m4/mkstemp.m4, m4/printf.m4, m4/sleep.m4, m4/stat.m4, m4/stdalign.m4, m4/stdint.m4, m4/strerror.m4, m4/string_h.m4, m4/sys_stat_h.m4, m4/sys_time_h.m4, m4/sys_types_h.m4, m4/time_h.m4, m4/unistd_h.m4, m4/wchar_h.m4, m4/wctype_h.m4, m4/wint_t.m4: Update.
99 lines
3 KiB
Text
99 lines
3 KiB
Text
# memchr.m4 serial 13
|
|
dnl Copyright (C) 2002-2004, 2009-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN_ONCE([gl_FUNC_MEMCHR],
|
|
[
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
|
|
dnl Check for prerequisites for memory fence checks.
|
|
gl_FUNC_MMAP_ANON
|
|
AC_CHECK_HEADERS_ONCE([sys/mman.h])
|
|
AC_CHECK_FUNCS_ONCE([mprotect])
|
|
|
|
AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
|
|
m4_ifdef([gl_FUNC_MEMCHR_OBSOLETE], [
|
|
dnl These days, we assume memchr is present. But if support for old
|
|
dnl platforms is desired:
|
|
AC_CHECK_FUNCS_ONCE([memchr])
|
|
if test $ac_cv_func_memchr = no; then
|
|
HAVE_MEMCHR=0
|
|
fi
|
|
])
|
|
if test $HAVE_MEMCHR = 1; then
|
|
# Detect platform-specific bugs in some versions of glibc:
|
|
# memchr should not dereference anything with length 0
|
|
# http://bugzilla.redhat.com/499689
|
|
# memchr should not dereference overestimated length after a match
|
|
# http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=521737
|
|
# http://sourceware.org/bugzilla/show_bug.cgi?id=10162
|
|
# Assume that memchr works on platforms that lack mprotect.
|
|
AC_CACHE_CHECK([whether memchr works], [gl_cv_func_memchr_works],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <string.h>
|
|
#if HAVE_SYS_MMAN_H
|
|
# include <fcntl.h>
|
|
# include <unistd.h>
|
|
# include <sys/types.h>
|
|
# include <sys/mman.h>
|
|
# ifndef MAP_FILE
|
|
# define MAP_FILE 0
|
|
# endif
|
|
#endif
|
|
]], [[
|
|
int result = 0;
|
|
char *fence = NULL;
|
|
#if HAVE_SYS_MMAN_H && HAVE_MPROTECT
|
|
# if HAVE_MAP_ANONYMOUS
|
|
const int flags = MAP_ANONYMOUS | MAP_PRIVATE;
|
|
const int fd = -1;
|
|
# else /* !HAVE_MAP_ANONYMOUS */
|
|
const int flags = MAP_FILE | MAP_PRIVATE;
|
|
int fd = open ("/dev/zero", O_RDONLY, 0666);
|
|
if (fd >= 0)
|
|
# endif
|
|
{
|
|
int pagesize = getpagesize ();
|
|
char *two_pages =
|
|
(char *) mmap (NULL, 2 * pagesize, PROT_READ | PROT_WRITE,
|
|
flags, fd, 0);
|
|
if (two_pages != (char *)(-1)
|
|
&& mprotect (two_pages + pagesize, pagesize, PROT_NONE) == 0)
|
|
fence = two_pages + pagesize;
|
|
}
|
|
#endif
|
|
if (fence)
|
|
{
|
|
if (memchr (fence, 0, 0))
|
|
result |= 1;
|
|
strcpy (fence - 9, "12345678");
|
|
if (memchr (fence - 9, 0, 79) != fence - 1)
|
|
result |= 2;
|
|
if (memchr (fence - 1, 0, 3) != fence - 1)
|
|
result |= 4;
|
|
}
|
|
return result;
|
|
]])],
|
|
[gl_cv_func_memchr_works=yes],
|
|
[gl_cv_func_memchr_works=no],
|
|
[case "$host_os" in
|
|
# Guess yes on native Windows.
|
|
mingw*) gl_cv_func_memchr_works="guessing yes" ;;
|
|
# Be pessimistic for now.
|
|
*) gl_cv_func_memchr_works="guessing no" ;;
|
|
esac
|
|
])
|
|
])
|
|
case "$gl_cv_func_memchr_works" in
|
|
*yes) ;;
|
|
*) REPLACE_MEMCHR=1 ;;
|
|
esac
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/memchr.c.
|
|
AC_DEFUN([gl_PREREQ_MEMCHR], [
|
|
AC_CHECK_HEADERS([bp-sym.h])
|
|
])
|