80d50c5665
* tools/snippet/_Noreturn.h, tools/snippet/c++defs.h, tools/snippet/arg-nonnull.h, tools/snippet/warn-on-use.h: Rename to... * lib/_Noreturn.h, lib/c++defs.h, lib/arg-nonnull.h, lib/warn-on-use.h: ... these. * lib/filename.h, lib/getopt-cdefs.in.h, lib/getopt-core.h, lib/getopt-ext.h, lib/getopt-pfx-core.h, lib/getopt-pfx-ext.h, lib/localtime-buffer.c, lib/localtime-buffer.h, lib/malloca.c, lib/malloca.h, lib/malloca.valgrind, lib/stat-w32.c, lib/stat-w32.h, m4/eealloc.m4, m4/localtime-buffer.m4, m4/malloca.m4: New files. * lib/argp-help.c, lib/argp-parse.c, lib/error.c, lib/float.in.h, lib/getopt1.c, lib/getopt.c, lib/getopt.in.h, lib/getopt_int.h, lib/gettext.h, lib/gettimeofday.c, lib/intprops.h, lib/isatty.c, lib/limits.in.h, lib/localcharset.c, lib/Makefile.am, lib/mbrtowc.c, lib/mbsinit.c, lib/msvc-nothrow.c, lib/quotearg.c, lib/stat.c, lib/stdalign.in.h, lib/stdint.in.h, lib/string.in.h, lib/sys_stat.in.h, lib/sys_types.in.h, lib/tempname.c, lib/time.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/wchar.in.h, lib/wctype.in.h, lib/xalloc.h, lib/xalloc-oversized.h, m4/fcntl-o.m4, m4/float_h.m4, m4/getopt.m4, m4/gettimeofday.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/include_next.m4, m4/largefile.m4, m4/lstat.m4, m4/mbrtowc.m4, m4/memchr.m4, m4/mkstemp.m4, m4/printf.m4, m4/sleep.m4, m4/stat.m4, m4/stdalign.m4, m4/stdint.m4, m4/strerror.m4, m4/string_h.m4, m4/sys_stat_h.m4, m4/sys_time_h.m4, m4/sys_types_h.m4, m4/time_h.m4, m4/unistd_h.m4, m4/wchar_h.m4, m4/wctype_h.m4, m4/wint_t.m4: Update.
84 lines
2.8 KiB
Text
84 lines
2.8 KiB
Text
#serial 24
|
|
|
|
# Copyright (C) 2001, 2003-2007, 2009-2017 Free Software Foundation, Inc.
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# On some hosts (e.g., HP-UX 10.20, SunOS 4.1.4, Solaris 2.5.1), mkstemp has a
|
|
# silly limit that it can create no more than 26 files from a given template.
|
|
# Other systems lack mkstemp altogether.
|
|
# On OSF1/Tru64 V4.0F, the system-provided mkstemp function can create
|
|
# only 32 files per process.
|
|
# On some hosts, mkstemp creates files with mode 0666, which is a security
|
|
# problem and a violation of POSIX 2008.
|
|
# On systems like the above, arrange to use the replacement function.
|
|
AC_DEFUN([gl_FUNC_MKSTEMP],
|
|
[
|
|
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
|
|
AC_CHECK_FUNCS_ONCE([mkstemp])
|
|
if test $ac_cv_func_mkstemp = yes; then
|
|
AC_CACHE_CHECK([for working mkstemp],
|
|
[gl_cv_func_working_mkstemp],
|
|
[
|
|
mkdir conftest.mkstemp
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[AC_INCLUDES_DEFAULT],
|
|
[[int result = 0;
|
|
int i;
|
|
off_t large = (off_t) 4294967295u;
|
|
if (large < 0)
|
|
large = 2147483647;
|
|
umask (0);
|
|
for (i = 0; i < 70; i++)
|
|
{
|
|
char templ[] = "conftest.mkstemp/coXXXXXX";
|
|
int (*mkstemp_function) (char *) = mkstemp;
|
|
int fd = mkstemp_function (templ);
|
|
if (fd < 0)
|
|
result |= 1;
|
|
else
|
|
{
|
|
struct stat st;
|
|
if (lseek (fd, large, SEEK_SET) != large)
|
|
result |= 2;
|
|
if (fstat (fd, &st) < 0)
|
|
result |= 4;
|
|
else if (st.st_mode & 0077)
|
|
result |= 8;
|
|
if (close (fd))
|
|
result |= 16;
|
|
}
|
|
}
|
|
return result;]])],
|
|
[gl_cv_func_working_mkstemp=yes],
|
|
[gl_cv_func_working_mkstemp=no],
|
|
[case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu*) gl_cv_func_working_mkstemp="guessing yes" ;;
|
|
# Guess no on native Windows.
|
|
mingw*) gl_cv_func_working_mkstemp="guessing no" ;;
|
|
# If we don't know, assume the worst.
|
|
*) gl_cv_func_working_mkstemp="guessing no" ;;
|
|
esac
|
|
])
|
|
rm -rf conftest.mkstemp
|
|
])
|
|
case "$gl_cv_func_working_mkstemp" in
|
|
*yes) ;;
|
|
*)
|
|
REPLACE_MKSTEMP=1
|
|
;;
|
|
esac
|
|
else
|
|
HAVE_MKSTEMP=0
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/mkstemp.c.
|
|
AC_DEFUN([gl_PREREQ_MKSTEMP],
|
|
[
|
|
])
|