93f6e21759
* lib/Makefile.am, lib/alloca.c, lib/alloca.in.h, lib/argp-ba.c, lib/argp-eexst.c, lib/argp-fmtstream.c, lib/argp-fmtstream.h, lib/argp-fs-xinl.c, lib/argp-help.c, lib/argp-namefrob.h, lib/argp-parse.c, lib/argp-pin.c, lib/argp-pv.c, lib/argp-pvh.c, lib/argp-xinl.c, lib/argp.h, lib/asnprintf.c, lib/basename-lgpl.c, lib/dirname-lgpl.c, lib/dirname.h, lib/dosname.h, lib/errno.in.h, lib/float+.h, lib/float.c, lib/float.in.h, lib/getopt.c, lib/getopt.in.h, lib/getopt1.c, lib/getopt_int.h, lib/gettext.h, lib/intprops.h, lib/itold.c, lib/malloc.c, lib/memchr.c, lib/memchr.valgrind, lib/mempcpy.c, lib/printf-args.c, lib/printf-args.h, lib/printf-parse.c, lib/printf-parse.h, lib/rawmemchr.c, lib/rawmemchr.valgrind, lib/size_max.h, lib/sleep.c, lib/stdalign.in.h, lib/stdbool.in.h, lib/stddef.in.h, lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h, lib/strcasecmp.c, lib/strchrnul.c, lib/strchrnul.valgrind, lib/strerror-override.c, lib/strerror-override.h, lib/strerror.c, lib/string.in.h, lib/strings.in.h, lib/stripslash.c, lib/strncasecmp.c, lib/strndup.c, lib/strnlen.c, lib/sys_types.in.h, lib/sysexits.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/vasnprintf.h, lib/verify.h, lib/vsnprintf.c, lib/wchar.in.h, lib/xsize.h, m4/00gnulib.m4, m4/alloca.m4, m4/argp.m4, m4/dirname.m4, m4/double-slash-root.m4, m4/errno_h.m4, m4/exponentd.m4, m4/extensions.m4, m4/float_h.m4, m4/getopt.m4, m4/gnulib-cache.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/gnulib-tool.m4, m4/include_next.m4, m4/intmax_t.m4, m4/inttypes_h.m4, m4/longlong.m4, m4/malloc.m4, m4/math_h.m4, m4/memchr.m4, m4/mempcpy.m4, m4/mmap-anon.m4, m4/multiarch.m4, m4/nocrash.m4, m4/off_t.m4, m4/printf.m4, m4/rawmemchr.m4, m4/size_max.m4, m4/sleep.m4, m4/ssize_t.m4, m4/stdalign.m4, m4/stdbool.m4, m4/stddef_h.m4, m4/stdint.m4, m4/stdint_h.m4, m4/stdio_h.m4, m4/stdlib_h.m4, m4/strcase.m4, m4/strchrnul.m4, m4/strerror.m4, m4/string_h.m4, m4/strings_h.m4, m4/strndup.m4, m4/strnlen.m4, m4/sys_socket_h.m4, m4/sys_types_h.m4, m4/sysexits.m4, m4/unistd_h.m4, m4/vasnprintf.m4, m4/vsnprintf.m4, m4/warn-on-use.m4, m4/wchar_h.m4, m4/wchar_t.m4, m4/wint_t.m4, m4/xsize.m4, tools/snippet/_Noreturn.h, tools/snippet/arg-nonnull.h, tools/snippet/c++defs.h, tools/snippet/warn-on-use.h: New files from gnulib 1af55d85d9762a679b4302d5995f05ccd883e956. * configure.ac, Makefile.am: Adjust to compile gnulib. * src/bin/Makefile.am: Adjust to use gnulib. * README: Mention lib/.
98 lines
2.4 KiB
Text
98 lines
2.4 KiB
Text
# float_h.m4 serial 9
|
|
dnl Copyright (C) 2007, 2009-2012 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FLOAT_H],
|
|
[
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
FLOAT_H=
|
|
REPLACE_FLOAT_LDBL=0
|
|
case "$host_os" in
|
|
aix* | beos* | openbsd* | mirbsd* | irix*)
|
|
FLOAT_H=float.h
|
|
;;
|
|
freebsd*)
|
|
case "$host_cpu" in
|
|
changequote(,)dnl
|
|
i[34567]86 )
|
|
changequote([,])dnl
|
|
FLOAT_H=float.h
|
|
;;
|
|
x86_64 )
|
|
# On x86_64 systems, the C compiler may still be generating
|
|
# 32-bit code.
|
|
AC_EGREP_CPP([yes],
|
|
[#if defined __LP64__ || defined __x86_64__ || defined __amd64__
|
|
yes
|
|
#endif],
|
|
[],
|
|
[FLOAT_H=float.h])
|
|
;;
|
|
esac
|
|
;;
|
|
linux*)
|
|
case "$host_cpu" in
|
|
powerpc*)
|
|
FLOAT_H=float.h
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
case "$host_os" in
|
|
aix* | freebsd* | linux*)
|
|
if test -n "$FLOAT_H"; then
|
|
REPLACE_FLOAT_LDBL=1
|
|
fi
|
|
;;
|
|
esac
|
|
|
|
dnl Test against glibc-2.7 Linux/SPARC64 bug.
|
|
REPLACE_ITOLD=0
|
|
AC_CACHE_CHECK([whether conversion from 'int' to 'long double' works],
|
|
[gl_cv_func_itold_works],
|
|
[
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_SOURCE([[
|
|
int i = -1;
|
|
volatile long double ld;
|
|
int main ()
|
|
{
|
|
ld += i * 1.0L;
|
|
if (ld > 0)
|
|
return 1;
|
|
return 0;
|
|
}]])],
|
|
[gl_cv_func_itold_works=yes],
|
|
[gl_cv_func_itold_works=no],
|
|
[case "$host" in
|
|
sparc*-*-linux*)
|
|
AC_EGREP_CPP([yes],
|
|
[#if defined __LP64__ || defined __arch64__
|
|
yes
|
|
#endif],
|
|
[gl_cv_func_itold_works="guessing no"],
|
|
[gl_cv_func_itold_works="guessing yes"])
|
|
;;
|
|
*) gl_cv_func_itold_works="guessing yes" ;;
|
|
esac
|
|
])
|
|
])
|
|
case "$gl_cv_func_itold_works" in
|
|
*no)
|
|
REPLACE_ITOLD=1
|
|
dnl We add the workaround to <float.h> but also to <math.h>,
|
|
dnl to increase the chances that the fix function gets pulled in.
|
|
FLOAT_H=float.h
|
|
;;
|
|
esac
|
|
|
|
if test -n "$FLOAT_H"; then
|
|
gl_NEXT_HEADERS([float.h])
|
|
fi
|
|
AC_SUBST([FLOAT_H])
|
|
AM_CONDITIONAL([GL_GENERATE_FLOAT_H], [test -n "$FLOAT_H"])
|
|
AC_SUBST([REPLACE_ITOLD])
|
|
])
|