93f6e21759
* lib/Makefile.am, lib/alloca.c, lib/alloca.in.h, lib/argp-ba.c, lib/argp-eexst.c, lib/argp-fmtstream.c, lib/argp-fmtstream.h, lib/argp-fs-xinl.c, lib/argp-help.c, lib/argp-namefrob.h, lib/argp-parse.c, lib/argp-pin.c, lib/argp-pv.c, lib/argp-pvh.c, lib/argp-xinl.c, lib/argp.h, lib/asnprintf.c, lib/basename-lgpl.c, lib/dirname-lgpl.c, lib/dirname.h, lib/dosname.h, lib/errno.in.h, lib/float+.h, lib/float.c, lib/float.in.h, lib/getopt.c, lib/getopt.in.h, lib/getopt1.c, lib/getopt_int.h, lib/gettext.h, lib/intprops.h, lib/itold.c, lib/malloc.c, lib/memchr.c, lib/memchr.valgrind, lib/mempcpy.c, lib/printf-args.c, lib/printf-args.h, lib/printf-parse.c, lib/printf-parse.h, lib/rawmemchr.c, lib/rawmemchr.valgrind, lib/size_max.h, lib/sleep.c, lib/stdalign.in.h, lib/stdbool.in.h, lib/stddef.in.h, lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h, lib/strcasecmp.c, lib/strchrnul.c, lib/strchrnul.valgrind, lib/strerror-override.c, lib/strerror-override.h, lib/strerror.c, lib/string.in.h, lib/strings.in.h, lib/stripslash.c, lib/strncasecmp.c, lib/strndup.c, lib/strnlen.c, lib/sys_types.in.h, lib/sysexits.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/vasnprintf.h, lib/verify.h, lib/vsnprintf.c, lib/wchar.in.h, lib/xsize.h, m4/00gnulib.m4, m4/alloca.m4, m4/argp.m4, m4/dirname.m4, m4/double-slash-root.m4, m4/errno_h.m4, m4/exponentd.m4, m4/extensions.m4, m4/float_h.m4, m4/getopt.m4, m4/gnulib-cache.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/gnulib-tool.m4, m4/include_next.m4, m4/intmax_t.m4, m4/inttypes_h.m4, m4/longlong.m4, m4/malloc.m4, m4/math_h.m4, m4/memchr.m4, m4/mempcpy.m4, m4/mmap-anon.m4, m4/multiarch.m4, m4/nocrash.m4, m4/off_t.m4, m4/printf.m4, m4/rawmemchr.m4, m4/size_max.m4, m4/sleep.m4, m4/ssize_t.m4, m4/stdalign.m4, m4/stdbool.m4, m4/stddef_h.m4, m4/stdint.m4, m4/stdint_h.m4, m4/stdio_h.m4, m4/stdlib_h.m4, m4/strcase.m4, m4/strchrnul.m4, m4/strerror.m4, m4/string_h.m4, m4/strings_h.m4, m4/strndup.m4, m4/strnlen.m4, m4/sys_socket_h.m4, m4/sys_types_h.m4, m4/sysexits.m4, m4/unistd_h.m4, m4/vasnprintf.m4, m4/vsnprintf.m4, m4/warn-on-use.m4, m4/wchar_h.m4, m4/wchar_t.m4, m4/wint_t.m4, m4/xsize.m4, tools/snippet/_Noreturn.h, tools/snippet/arg-nonnull.h, tools/snippet/c++defs.h, tools/snippet/warn-on-use.h: New files from gnulib 1af55d85d9762a679b4302d5995f05ccd883e956. * configure.ac, Makefile.am: Adjust to compile gnulib. * src/bin/Makefile.am: Adjust to use gnulib. * README: Mention lib/.
134 lines
3.1 KiB
Text
134 lines
3.1 KiB
Text
# errno_h.m4 serial 11
|
|
dnl Copyright (C) 2004, 2006, 2008-2012 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN_ONCE([gl_HEADER_ERRNO_H],
|
|
[
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_CACHE_CHECK([for complete errno.h], [gl_cv_header_errno_h_complete], [
|
|
AC_EGREP_CPP([booboo],[
|
|
#include <errno.h>
|
|
#if !defined ETXTBSY
|
|
booboo
|
|
#endif
|
|
#if !defined ENOMSG
|
|
booboo
|
|
#endif
|
|
#if !defined EIDRM
|
|
booboo
|
|
#endif
|
|
#if !defined ENOLINK
|
|
booboo
|
|
#endif
|
|
#if !defined EPROTO
|
|
booboo
|
|
#endif
|
|
#if !defined EMULTIHOP
|
|
booboo
|
|
#endif
|
|
#if !defined EBADMSG
|
|
booboo
|
|
#endif
|
|
#if !defined EOVERFLOW
|
|
booboo
|
|
#endif
|
|
#if !defined ENOTSUP
|
|
booboo
|
|
#endif
|
|
#if !defined ENETRESET
|
|
booboo
|
|
#endif
|
|
#if !defined ECONNABORTED
|
|
booboo
|
|
#endif
|
|
#if !defined ESTALE
|
|
booboo
|
|
#endif
|
|
#if !defined EDQUOT
|
|
booboo
|
|
#endif
|
|
#if !defined ECANCELED
|
|
booboo
|
|
#endif
|
|
#if !defined EOWNERDEAD
|
|
booboo
|
|
#endif
|
|
#if !defined ENOTRECOVERABLE
|
|
booboo
|
|
#endif
|
|
],
|
|
[gl_cv_header_errno_h_complete=no],
|
|
[gl_cv_header_errno_h_complete=yes])
|
|
])
|
|
if test $gl_cv_header_errno_h_complete = yes; then
|
|
ERRNO_H=''
|
|
else
|
|
gl_NEXT_HEADERS([errno.h])
|
|
ERRNO_H='errno.h'
|
|
fi
|
|
AC_SUBST([ERRNO_H])
|
|
AM_CONDITIONAL([GL_GENERATE_ERRNO_H], [test -n "$ERRNO_H"])
|
|
gl_REPLACE_ERRNO_VALUE([EMULTIHOP])
|
|
gl_REPLACE_ERRNO_VALUE([ENOLINK])
|
|
gl_REPLACE_ERRNO_VALUE([EOVERFLOW])
|
|
])
|
|
|
|
# Assuming $1 = EOVERFLOW.
|
|
# The EOVERFLOW errno value ought to be defined in <errno.h>, according to
|
|
# POSIX. But some systems (like OpenBSD 4.0 or AIX 3) don't define it, and
|
|
# some systems (like OSF/1) define it when _XOPEN_SOURCE_EXTENDED is defined.
|
|
# Check for the value of EOVERFLOW.
|
|
# Set the variables EOVERFLOW_HIDDEN and EOVERFLOW_VALUE.
|
|
AC_DEFUN([gl_REPLACE_ERRNO_VALUE],
|
|
[
|
|
if test -n "$ERRNO_H"; then
|
|
AC_CACHE_CHECK([for ]$1[ value], [gl_cv_header_errno_h_]$1, [
|
|
AC_EGREP_CPP([yes],[
|
|
#include <errno.h>
|
|
#ifdef ]$1[
|
|
yes
|
|
#endif
|
|
],
|
|
[gl_cv_header_errno_h_]$1[=yes],
|
|
[gl_cv_header_errno_h_]$1[=no])
|
|
if test $gl_cv_header_errno_h_]$1[ = no; then
|
|
AC_EGREP_CPP([yes],[
|
|
#define _XOPEN_SOURCE_EXTENDED 1
|
|
#include <errno.h>
|
|
#ifdef ]$1[
|
|
yes
|
|
#endif
|
|
], [gl_cv_header_errno_h_]$1[=hidden])
|
|
if test $gl_cv_header_errno_h_]$1[ = hidden; then
|
|
dnl The macro exists but is hidden.
|
|
dnl Define it to the same value.
|
|
AC_COMPUTE_INT([gl_cv_header_errno_h_]$1, $1, [
|
|
#define _XOPEN_SOURCE_EXTENDED 1
|
|
#include <errno.h>
|
|
/* The following two lines are a workaround against an autoconf-2.52 bug. */
|
|
#include <stdio.h>
|
|
#include <stdlib.h>
|
|
])
|
|
fi
|
|
fi
|
|
])
|
|
case $gl_cv_header_errno_h_]$1[ in
|
|
yes | no)
|
|
]$1[_HIDDEN=0; ]$1[_VALUE=
|
|
;;
|
|
*)
|
|
]$1[_HIDDEN=1; ]$1[_VALUE="$gl_cv_header_errno_h_]$1["
|
|
;;
|
|
esac
|
|
AC_SUBST($1[_HIDDEN])
|
|
AC_SUBST($1[_VALUE])
|
|
fi
|
|
])
|
|
|
|
dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
|
|
dnl Remove this when we can assume autoconf >= 2.61.
|
|
m4_ifdef([AC_COMPUTE_INT], [], [
|
|
AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
|
|
])
|