93f6e21759
* lib/Makefile.am, lib/alloca.c, lib/alloca.in.h, lib/argp-ba.c, lib/argp-eexst.c, lib/argp-fmtstream.c, lib/argp-fmtstream.h, lib/argp-fs-xinl.c, lib/argp-help.c, lib/argp-namefrob.h, lib/argp-parse.c, lib/argp-pin.c, lib/argp-pv.c, lib/argp-pvh.c, lib/argp-xinl.c, lib/argp.h, lib/asnprintf.c, lib/basename-lgpl.c, lib/dirname-lgpl.c, lib/dirname.h, lib/dosname.h, lib/errno.in.h, lib/float+.h, lib/float.c, lib/float.in.h, lib/getopt.c, lib/getopt.in.h, lib/getopt1.c, lib/getopt_int.h, lib/gettext.h, lib/intprops.h, lib/itold.c, lib/malloc.c, lib/memchr.c, lib/memchr.valgrind, lib/mempcpy.c, lib/printf-args.c, lib/printf-args.h, lib/printf-parse.c, lib/printf-parse.h, lib/rawmemchr.c, lib/rawmemchr.valgrind, lib/size_max.h, lib/sleep.c, lib/stdalign.in.h, lib/stdbool.in.h, lib/stddef.in.h, lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h, lib/strcasecmp.c, lib/strchrnul.c, lib/strchrnul.valgrind, lib/strerror-override.c, lib/strerror-override.h, lib/strerror.c, lib/string.in.h, lib/strings.in.h, lib/stripslash.c, lib/strncasecmp.c, lib/strndup.c, lib/strnlen.c, lib/sys_types.in.h, lib/sysexits.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/vasnprintf.h, lib/verify.h, lib/vsnprintf.c, lib/wchar.in.h, lib/xsize.h, m4/00gnulib.m4, m4/alloca.m4, m4/argp.m4, m4/dirname.m4, m4/double-slash-root.m4, m4/errno_h.m4, m4/exponentd.m4, m4/extensions.m4, m4/float_h.m4, m4/getopt.m4, m4/gnulib-cache.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/gnulib-tool.m4, m4/include_next.m4, m4/intmax_t.m4, m4/inttypes_h.m4, m4/longlong.m4, m4/malloc.m4, m4/math_h.m4, m4/memchr.m4, m4/mempcpy.m4, m4/mmap-anon.m4, m4/multiarch.m4, m4/nocrash.m4, m4/off_t.m4, m4/printf.m4, m4/rawmemchr.m4, m4/size_max.m4, m4/sleep.m4, m4/ssize_t.m4, m4/stdalign.m4, m4/stdbool.m4, m4/stddef_h.m4, m4/stdint.m4, m4/stdint_h.m4, m4/stdio_h.m4, m4/stdlib_h.m4, m4/strcase.m4, m4/strchrnul.m4, m4/strerror.m4, m4/string_h.m4, m4/strings_h.m4, m4/strndup.m4, m4/strnlen.m4, m4/sys_socket_h.m4, m4/sys_types_h.m4, m4/sysexits.m4, m4/unistd_h.m4, m4/vasnprintf.m4, m4/vsnprintf.m4, m4/warn-on-use.m4, m4/wchar_h.m4, m4/wchar_t.m4, m4/wint_t.m4, m4/xsize.m4, tools/snippet/_Noreturn.h, tools/snippet/arg-nonnull.h, tools/snippet/c++defs.h, tools/snippet/warn-on-use.h: New files from gnulib 1af55d85d9762a679b4302d5995f05ccd883e956. * configure.ac, Makefile.am: Adjust to compile gnulib. * src/bin/Makefile.am: Adjust to use gnulib. * README: Mention lib/.
54 lines
1.6 KiB
Text
54 lines
1.6 KiB
Text
# vsnprintf.m4 serial 6
|
|
dnl Copyright (C) 2002-2004, 2007-2012 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl Libintl 0.17 will replace vsnprintf only if it does not support %1$s,
|
|
dnl but defers to any gnulib vsnprintf replacements. Therefore, gnulib
|
|
dnl must guarantee that the decision for replacing vsnprintf is a superset
|
|
dnl of the reasons checked by libintl.
|
|
AC_DEFUN([gl_FUNC_VSNPRINTF],
|
|
[
|
|
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
|
|
gl_cv_func_vsnprintf_usable=no
|
|
AC_CHECK_FUNCS([vsnprintf])
|
|
if test $ac_cv_func_vsnprintf = yes; then
|
|
gl_SNPRINTF_SIZE1
|
|
case "$gl_cv_func_snprintf_size1" in
|
|
*yes)
|
|
gl_SNPRINTF_RETVAL_C99
|
|
case "$gl_cv_func_snprintf_retval_c99" in
|
|
*yes)
|
|
gl_PRINTF_POSITIONS
|
|
case "$gl_cv_func_printf_positions" in
|
|
*yes)
|
|
gl_cv_func_vsnprintf_usable=yes
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
;;
|
|
esac
|
|
fi
|
|
if test $gl_cv_func_vsnprintf_usable = no; then
|
|
gl_REPLACE_VSNPRINTF
|
|
fi
|
|
AC_CHECK_DECLS_ONCE([vsnprintf])
|
|
if test $ac_cv_have_decl_vsnprintf = no; then
|
|
HAVE_DECL_VSNPRINTF=0
|
|
fi
|
|
])
|
|
|
|
AC_DEFUN([gl_REPLACE_VSNPRINTF],
|
|
[
|
|
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
|
|
AC_LIBOBJ([vsnprintf])
|
|
if test $ac_cv_func_vsnprintf = yes; then
|
|
REPLACE_VSNPRINTF=1
|
|
fi
|
|
gl_PREREQ_VSNPRINTF
|
|
])
|
|
|
|
# Prerequisites of lib/vsnprintf.c.
|
|
AC_DEFUN([gl_PREREQ_VSNPRINTF], [:])
|