f8cdaf0c12
* lib/Makefile.am lib/alloca.in.h lib/argp-ba.c lib/argp-eexst.c lib/argp-fmtstream.c lib/argp-fmtstream.h lib/argp-fs-xinl.c lib/argp-help.c lib/argp-namefrob.h lib/argp-parse.c lib/argp-pin.c lib/argp-pv.c lib/argp-pvh.c lib/argp-xinl.c lib/argp.h lib/asnprintf.c lib/basename-lgpl.c lib/dirname-lgpl.c lib/dirname.h lib/dosname.h lib/errno.in.h lib/error.c lib/error.h lib/fcntl.in.h lib/float+.h lib/float.c lib/float.in.h lib/gethrxtime.c lib/gethrxtime.h lib/getopt.c lib/getopt.in.h lib/getopt1.c lib/getopt_int.h lib/gettext.h lib/gettime.c lib/gettimeofday.c lib/intprops.h lib/itold.c lib/lstat.c lib/malloc.c lib/memchr.c lib/mempcpy.c lib/mkstemp.c lib/msvc-inval.c lib/msvc-inval.h lib/msvc-nothrow.c lib/msvc-nothrow.h lib/pathmax.h lib/printf-args.c lib/printf-args.h lib/printf-parse.c lib/printf-parse.h lib/progname.c lib/progname.h lib/rawmemchr.c lib/size_max.h lib/sleep.c lib/stat.c lib/stdalign.in.h lib/stdbool.in.h lib/stddef.in.h lib/stdint.in.h lib/stdio.in.h lib/stdlib.in.h lib/strcasecmp.c lib/strchrnul.c lib/strerror-override.c lib/strerror-override.h lib/strerror.c lib/string.in.h lib/strings.in.h lib/stripslash.c lib/strncasecmp.c lib/strndup.c lib/strnlen.c lib/sys_stat.in.h lib/sys_time.in.h lib/sys_types.in.h lib/sys_wait.in.h lib/sysexits.in.h lib/tempname.c lib/tempname.h lib/time.in.h lib/timespec.h lib/unistd.in.h lib/vasnprintf.c lib/vasnprintf.h lib/verify.h lib/vsnprintf.c lib/wchar.in.h lib/xsize.h lib/xtime.h m4/00gnulib.m4 m4/alloca.m4 m4/argp.m4 m4/clock_time.m4 m4/dirname.m4 m4/double-slash-root.m4 m4/errno_h.m4 m4/error.m4 m4/exponentd.m4 m4/extensions.m4 m4/extern-inline.m4 m4/fcntl-o.m4 m4/fcntl_h.m4 m4/float_h.m4 m4/gethrxtime.m4 m4/getopt.m4 m4/gettime.m4 m4/gettimeofday.m4 m4/gnulib-cache.m4 m4/gnulib-common.m4 m4/gnulib-comp.m4 m4/gnulib-tool.m4 m4/include_next.m4 m4/intmax_t.m4 m4/inttypes_h.m4 m4/largefile.m4 m4/longlong.m4 m4/lstat.m4 m4/malloc.m4 m4/math_h.m4 m4/memchr.m4 m4/mempcpy.m4 m4/mkstemp.m4 m4/mmap-anon.m4 m4/msvc-inval.m4 m4/msvc-nothrow.m4 m4/multiarch.m4 m4/nocrash.m4 m4/off_t.m4 m4/pathmax.m4 m4/printf.m4 m4/rawmemchr.m4 m4/size_max.m4 m4/sleep.m4 m4/ssize_t.m4 m4/stat.m4 m4/stdalign.m4 m4/stdbool.m4 m4/stddef_h.m4 m4/stdint.m4 m4/stdint_h.m4 m4/stdio_h.m4 m4/stdlib_h.m4 m4/strcase.m4 m4/strchrnul.m4 m4/strerror.m4 m4/string_h.m4 m4/strings_h.m4 m4/strndup.m4 m4/strnlen.m4 m4/sys_socket_h.m4 m4/sys_stat_h.m4 m4/sys_time_h.m4 m4/sys_types_h.m4 m4/sys_wait_h.m4 m4/sysexits.m4 m4/tempname.m4 m4/time_h.m4 m4/timespec.m4 m4/unistd_h.m4 m4/vasnprintf.m4 m4/vsnprintf.m4 m4/warn-on-use.m4 m4/wchar_h.m4 m4/wchar_t.m4 m4/wint_t.m4 m4/xsize.m4 tools/snippet/arg-nonnull.h tools/snippet/c++defs.h tools/snippet/warn-on-use.h: Upgrade to gnulib 9ceceed274f83094127f9ff0bf061293c9fe1e7f. * m4/secure_getenv.m4, lib/secure_getenv.c, lib/unistd.c, lib/xtime.c: New files. * src/bin/Makefile.am: Link with the libtool library.
50 lines
1.5 KiB
Text
50 lines
1.5 KiB
Text
# strchrnul.m4 serial 9
|
|
dnl Copyright (C) 2003, 2007, 2009-2013 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_STRCHRNUL],
|
|
[
|
|
dnl Persuade glibc <string.h> to declare strchrnul().
|
|
AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
|
|
|
|
AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
|
|
AC_CHECK_FUNCS([strchrnul])
|
|
if test $ac_cv_func_strchrnul = no; then
|
|
HAVE_STRCHRNUL=0
|
|
else
|
|
AC_CACHE_CHECK([whether strchrnul works],
|
|
[gl_cv_func_strchrnul_works],
|
|
[AC_RUN_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <string.h> /* for strchrnul */
|
|
]], [[const char *buf = "a";
|
|
return strchrnul (buf, 'b') != buf + 1;
|
|
]])],
|
|
[gl_cv_func_strchrnul_works=yes],
|
|
[gl_cv_func_strchrnul_works=no],
|
|
[dnl Cygwin 1.7.9 introduced strchrnul, but it was broken until 1.7.10
|
|
AC_EGREP_CPP([Lucky user],
|
|
[
|
|
#if defined __CYGWIN__
|
|
#include <cygwin/version.h>
|
|
#if CYGWIN_VERSION_DLL_COMBINED > CYGWIN_VERSION_DLL_MAKE_COMBINED (1007, 9)
|
|
Lucky user
|
|
#endif
|
|
#else
|
|
Lucky user
|
|
#endif
|
|
],
|
|
[gl_cv_func_strchrnul_works="guessing yes"],
|
|
[gl_cv_func_strchrnul_works="guessing no"])
|
|
])
|
|
])
|
|
case "$gl_cv_func_strchrnul_works" in
|
|
*yes) ;;
|
|
*) REPLACE_STRCHRNUL=1 ;;
|
|
esac
|
|
fi
|
|
])
|
|
|
|
# Prerequisites of lib/strchrnul.c.
|
|
AC_DEFUN([gl_PREREQ_STRCHRNUL], [:])
|