93f6e21759
* lib/Makefile.am, lib/alloca.c, lib/alloca.in.h, lib/argp-ba.c, lib/argp-eexst.c, lib/argp-fmtstream.c, lib/argp-fmtstream.h, lib/argp-fs-xinl.c, lib/argp-help.c, lib/argp-namefrob.h, lib/argp-parse.c, lib/argp-pin.c, lib/argp-pv.c, lib/argp-pvh.c, lib/argp-xinl.c, lib/argp.h, lib/asnprintf.c, lib/basename-lgpl.c, lib/dirname-lgpl.c, lib/dirname.h, lib/dosname.h, lib/errno.in.h, lib/float+.h, lib/float.c, lib/float.in.h, lib/getopt.c, lib/getopt.in.h, lib/getopt1.c, lib/getopt_int.h, lib/gettext.h, lib/intprops.h, lib/itold.c, lib/malloc.c, lib/memchr.c, lib/memchr.valgrind, lib/mempcpy.c, lib/printf-args.c, lib/printf-args.h, lib/printf-parse.c, lib/printf-parse.h, lib/rawmemchr.c, lib/rawmemchr.valgrind, lib/size_max.h, lib/sleep.c, lib/stdalign.in.h, lib/stdbool.in.h, lib/stddef.in.h, lib/stdint.in.h, lib/stdio.in.h, lib/stdlib.in.h, lib/strcasecmp.c, lib/strchrnul.c, lib/strchrnul.valgrind, lib/strerror-override.c, lib/strerror-override.h, lib/strerror.c, lib/string.in.h, lib/strings.in.h, lib/stripslash.c, lib/strncasecmp.c, lib/strndup.c, lib/strnlen.c, lib/sys_types.in.h, lib/sysexits.in.h, lib/unistd.in.h, lib/vasnprintf.c, lib/vasnprintf.h, lib/verify.h, lib/vsnprintf.c, lib/wchar.in.h, lib/xsize.h, m4/00gnulib.m4, m4/alloca.m4, m4/argp.m4, m4/dirname.m4, m4/double-slash-root.m4, m4/errno_h.m4, m4/exponentd.m4, m4/extensions.m4, m4/float_h.m4, m4/getopt.m4, m4/gnulib-cache.m4, m4/gnulib-common.m4, m4/gnulib-comp.m4, m4/gnulib-tool.m4, m4/include_next.m4, m4/intmax_t.m4, m4/inttypes_h.m4, m4/longlong.m4, m4/malloc.m4, m4/math_h.m4, m4/memchr.m4, m4/mempcpy.m4, m4/mmap-anon.m4, m4/multiarch.m4, m4/nocrash.m4, m4/off_t.m4, m4/printf.m4, m4/rawmemchr.m4, m4/size_max.m4, m4/sleep.m4, m4/ssize_t.m4, m4/stdalign.m4, m4/stdbool.m4, m4/stddef_h.m4, m4/stdint.m4, m4/stdint_h.m4, m4/stdio_h.m4, m4/stdlib_h.m4, m4/strcase.m4, m4/strchrnul.m4, m4/strerror.m4, m4/string_h.m4, m4/strings_h.m4, m4/strndup.m4, m4/strnlen.m4, m4/sys_socket_h.m4, m4/sys_types_h.m4, m4/sysexits.m4, m4/unistd_h.m4, m4/vasnprintf.m4, m4/vsnprintf.m4, m4/warn-on-use.m4, m4/wchar_h.m4, m4/wchar_t.m4, m4/wint_t.m4, m4/xsize.m4, tools/snippet/_Noreturn.h, tools/snippet/arg-nonnull.h, tools/snippet/c++defs.h, tools/snippet/warn-on-use.h: New files from gnulib 1af55d85d9762a679b4302d5995f05ccd883e956. * configure.ac, Makefile.am: Adjust to compile gnulib. * src/bin/Makefile.am: Adjust to use gnulib. * README: Mention lib/.
98 lines
3.2 KiB
Text
98 lines
3.2 KiB
Text
# malloc.m4 serial 14
|
|
dnl Copyright (C) 2007, 2009-2012 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
m4_version_prereq([2.70], [] ,[
|
|
|
|
# This is taken from the following Autoconf patch:
|
|
# http://git.savannah.gnu.org/gitweb/?p=autoconf.git;a=commitdiff;h=7fbb553727ed7e0e689a17594b58559ecf3ea6e9
|
|
AC_DEFUN([_AC_FUNC_MALLOC_IF],
|
|
[
|
|
AC_REQUIRE([AC_HEADER_STDC])dnl
|
|
AC_REQUIRE([AC_CANONICAL_HOST])dnl for cross-compiles
|
|
AC_CHECK_HEADERS([stdlib.h])
|
|
AC_CACHE_CHECK([for GNU libc compatible malloc],
|
|
[ac_cv_func_malloc_0_nonnull],
|
|
[AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#if defined STDC_HEADERS || defined HAVE_STDLIB_H
|
|
# include <stdlib.h>
|
|
#else
|
|
char *malloc ();
|
|
#endif
|
|
]],
|
|
[[return ! malloc (0);]])
|
|
],
|
|
[ac_cv_func_malloc_0_nonnull=yes],
|
|
[ac_cv_func_malloc_0_nonnull=no],
|
|
[case "$host_os" in
|
|
# Guess yes on platforms where we know the result.
|
|
*-gnu* | freebsd* | netbsd* | openbsd* \
|
|
| hpux* | solaris* | cygwin* | mingw*)
|
|
ac_cv_func_malloc_0_nonnull=yes ;;
|
|
# If we don't know, assume the worst.
|
|
*) ac_cv_func_malloc_0_nonnull=no ;;
|
|
esac
|
|
])
|
|
])
|
|
AS_IF([test $ac_cv_func_malloc_0_nonnull = yes], [$1], [$2])
|
|
])# _AC_FUNC_MALLOC_IF
|
|
|
|
])
|
|
|
|
# gl_FUNC_MALLOC_GNU
|
|
# ------------------
|
|
# Test whether 'malloc (0)' is handled like in GNU libc, and replace malloc if
|
|
# it is not.
|
|
AC_DEFUN([gl_FUNC_MALLOC_GNU],
|
|
[
|
|
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
|
|
dnl _AC_FUNC_MALLOC_IF is defined in Autoconf.
|
|
_AC_FUNC_MALLOC_IF(
|
|
[AC_DEFINE([HAVE_MALLOC_GNU], [1],
|
|
[Define to 1 if your system has a GNU libc compatible 'malloc'
|
|
function, and to 0 otherwise.])],
|
|
[AC_DEFINE([HAVE_MALLOC_GNU], [0])
|
|
REPLACE_MALLOC=1
|
|
])
|
|
])
|
|
|
|
# gl_FUNC_MALLOC_POSIX
|
|
# --------------------
|
|
# Test whether 'malloc' is POSIX compliant (sets errno to ENOMEM when it
|
|
# fails), and replace malloc if it is not.
|
|
AC_DEFUN([gl_FUNC_MALLOC_POSIX],
|
|
[
|
|
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
|
|
AC_REQUIRE([gl_CHECK_MALLOC_POSIX])
|
|
if test $gl_cv_func_malloc_posix = yes; then
|
|
AC_DEFINE([HAVE_MALLOC_POSIX], [1],
|
|
[Define if the 'malloc' function is POSIX compliant.])
|
|
else
|
|
REPLACE_MALLOC=1
|
|
fi
|
|
])
|
|
|
|
# Test whether malloc, realloc, calloc are POSIX compliant,
|
|
# Set gl_cv_func_malloc_posix to yes or no accordingly.
|
|
AC_DEFUN([gl_CHECK_MALLOC_POSIX],
|
|
[
|
|
AC_CACHE_CHECK([whether malloc, realloc, calloc are POSIX compliant],
|
|
[gl_cv_func_malloc_posix],
|
|
[
|
|
dnl It is too dangerous to try to allocate a large amount of memory:
|
|
dnl some systems go to their knees when you do that. So assume that
|
|
dnl all Unix implementations of the function are POSIX compliant.
|
|
AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[]],
|
|
[[#if (defined _WIN32 || defined __WIN32__) && ! defined __CYGWIN__
|
|
choke me
|
|
#endif
|
|
]])],
|
|
[gl_cv_func_malloc_posix=yes],
|
|
[gl_cv_func_malloc_posix=no])
|
|
])
|
|
])
|