f8cdaf0c12
* lib/Makefile.am lib/alloca.in.h lib/argp-ba.c lib/argp-eexst.c lib/argp-fmtstream.c lib/argp-fmtstream.h lib/argp-fs-xinl.c lib/argp-help.c lib/argp-namefrob.h lib/argp-parse.c lib/argp-pin.c lib/argp-pv.c lib/argp-pvh.c lib/argp-xinl.c lib/argp.h lib/asnprintf.c lib/basename-lgpl.c lib/dirname-lgpl.c lib/dirname.h lib/dosname.h lib/errno.in.h lib/error.c lib/error.h lib/fcntl.in.h lib/float+.h lib/float.c lib/float.in.h lib/gethrxtime.c lib/gethrxtime.h lib/getopt.c lib/getopt.in.h lib/getopt1.c lib/getopt_int.h lib/gettext.h lib/gettime.c lib/gettimeofday.c lib/intprops.h lib/itold.c lib/lstat.c lib/malloc.c lib/memchr.c lib/mempcpy.c lib/mkstemp.c lib/msvc-inval.c lib/msvc-inval.h lib/msvc-nothrow.c lib/msvc-nothrow.h lib/pathmax.h lib/printf-args.c lib/printf-args.h lib/printf-parse.c lib/printf-parse.h lib/progname.c lib/progname.h lib/rawmemchr.c lib/size_max.h lib/sleep.c lib/stat.c lib/stdalign.in.h lib/stdbool.in.h lib/stddef.in.h lib/stdint.in.h lib/stdio.in.h lib/stdlib.in.h lib/strcasecmp.c lib/strchrnul.c lib/strerror-override.c lib/strerror-override.h lib/strerror.c lib/string.in.h lib/strings.in.h lib/stripslash.c lib/strncasecmp.c lib/strndup.c lib/strnlen.c lib/sys_stat.in.h lib/sys_time.in.h lib/sys_types.in.h lib/sys_wait.in.h lib/sysexits.in.h lib/tempname.c lib/tempname.h lib/time.in.h lib/timespec.h lib/unistd.in.h lib/vasnprintf.c lib/vasnprintf.h lib/verify.h lib/vsnprintf.c lib/wchar.in.h lib/xsize.h lib/xtime.h m4/00gnulib.m4 m4/alloca.m4 m4/argp.m4 m4/clock_time.m4 m4/dirname.m4 m4/double-slash-root.m4 m4/errno_h.m4 m4/error.m4 m4/exponentd.m4 m4/extensions.m4 m4/extern-inline.m4 m4/fcntl-o.m4 m4/fcntl_h.m4 m4/float_h.m4 m4/gethrxtime.m4 m4/getopt.m4 m4/gettime.m4 m4/gettimeofday.m4 m4/gnulib-cache.m4 m4/gnulib-common.m4 m4/gnulib-comp.m4 m4/gnulib-tool.m4 m4/include_next.m4 m4/intmax_t.m4 m4/inttypes_h.m4 m4/largefile.m4 m4/longlong.m4 m4/lstat.m4 m4/malloc.m4 m4/math_h.m4 m4/memchr.m4 m4/mempcpy.m4 m4/mkstemp.m4 m4/mmap-anon.m4 m4/msvc-inval.m4 m4/msvc-nothrow.m4 m4/multiarch.m4 m4/nocrash.m4 m4/off_t.m4 m4/pathmax.m4 m4/printf.m4 m4/rawmemchr.m4 m4/size_max.m4 m4/sleep.m4 m4/ssize_t.m4 m4/stat.m4 m4/stdalign.m4 m4/stdbool.m4 m4/stddef_h.m4 m4/stdint.m4 m4/stdint_h.m4 m4/stdio_h.m4 m4/stdlib_h.m4 m4/strcase.m4 m4/strchrnul.m4 m4/strerror.m4 m4/string_h.m4 m4/strings_h.m4 m4/strndup.m4 m4/strnlen.m4 m4/sys_socket_h.m4 m4/sys_stat_h.m4 m4/sys_time_h.m4 m4/sys_types_h.m4 m4/sys_wait_h.m4 m4/sysexits.m4 m4/tempname.m4 m4/time_h.m4 m4/timespec.m4 m4/unistd_h.m4 m4/vasnprintf.m4 m4/vsnprintf.m4 m4/warn-on-use.m4 m4/wchar_h.m4 m4/wchar_t.m4 m4/wint_t.m4 m4/xsize.m4 tools/snippet/arg-nonnull.h tools/snippet/c++defs.h tools/snippet/warn-on-use.h: Upgrade to gnulib 9ceceed274f83094127f9ff0bf061293c9fe1e7f. * m4/secure_getenv.m4, lib/secure_getenv.c, lib/unistd.c, lib/xtime.c: New files. * src/bin/Makefile.am: Link with the libtool library.
113 lines
4.6 KiB
Text
113 lines
4.6 KiB
Text
# longlong.m4 serial 17
|
|
dnl Copyright (C) 1999-2007, 2009-2013 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Paul Eggert.
|
|
|
|
# Define HAVE_LONG_LONG_INT if 'long long int' works.
|
|
# This fixes a bug in Autoconf 2.61, and can be faster
|
|
# than what's in Autoconf 2.62 through 2.68.
|
|
|
|
# Note: If the type 'long long int' exists but is only 32 bits large
|
|
# (as on some very old compilers), HAVE_LONG_LONG_INT will not be
|
|
# defined. In this case you can treat 'long long int' like 'long int'.
|
|
|
|
AC_DEFUN([AC_TYPE_LONG_LONG_INT],
|
|
[
|
|
AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
|
|
AC_CACHE_CHECK([for long long int], [ac_cv_type_long_long_int],
|
|
[ac_cv_type_long_long_int=yes
|
|
if test "x${ac_cv_prog_cc_c99-no}" = xno; then
|
|
ac_cv_type_long_long_int=$ac_cv_type_unsigned_long_long_int
|
|
if test $ac_cv_type_long_long_int = yes; then
|
|
dnl Catch a bug in Tandem NonStop Kernel (OSS) cc -O circa 2004.
|
|
dnl If cross compiling, assume the bug is not important, since
|
|
dnl nobody cross compiles for this platform as far as we know.
|
|
AC_RUN_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[@%:@include <limits.h>
|
|
@%:@ifndef LLONG_MAX
|
|
@%:@ define HALF \
|
|
(1LL << (sizeof (long long int) * CHAR_BIT - 2))
|
|
@%:@ define LLONG_MAX (HALF - 1 + HALF)
|
|
@%:@endif]],
|
|
[[long long int n = 1;
|
|
int i;
|
|
for (i = 0; ; i++)
|
|
{
|
|
long long int m = n << i;
|
|
if (m >> i != n)
|
|
return 1;
|
|
if (LLONG_MAX / 2 < m)
|
|
break;
|
|
}
|
|
return 0;]])],
|
|
[],
|
|
[ac_cv_type_long_long_int=no],
|
|
[:])
|
|
fi
|
|
fi])
|
|
if test $ac_cv_type_long_long_int = yes; then
|
|
AC_DEFINE([HAVE_LONG_LONG_INT], [1],
|
|
[Define to 1 if the system has the type 'long long int'.])
|
|
fi
|
|
])
|
|
|
|
# Define HAVE_UNSIGNED_LONG_LONG_INT if 'unsigned long long int' works.
|
|
# This fixes a bug in Autoconf 2.61, and can be faster
|
|
# than what's in Autoconf 2.62 through 2.68.
|
|
|
|
# Note: If the type 'unsigned long long int' exists but is only 32 bits
|
|
# large (as on some very old compilers), AC_TYPE_UNSIGNED_LONG_LONG_INT
|
|
# will not be defined. In this case you can treat 'unsigned long long int'
|
|
# like 'unsigned long int'.
|
|
|
|
AC_DEFUN([AC_TYPE_UNSIGNED_LONG_LONG_INT],
|
|
[
|
|
AC_CACHE_CHECK([for unsigned long long int],
|
|
[ac_cv_type_unsigned_long_long_int],
|
|
[ac_cv_type_unsigned_long_long_int=yes
|
|
if test "x${ac_cv_prog_cc_c99-no}" = xno; then
|
|
AC_LINK_IFELSE(
|
|
[_AC_TYPE_LONG_LONG_SNIPPET],
|
|
[],
|
|
[ac_cv_type_unsigned_long_long_int=no])
|
|
fi])
|
|
if test $ac_cv_type_unsigned_long_long_int = yes; then
|
|
AC_DEFINE([HAVE_UNSIGNED_LONG_LONG_INT], [1],
|
|
[Define to 1 if the system has the type 'unsigned long long int'.])
|
|
fi
|
|
])
|
|
|
|
# Expands to a C program that can be used to test for simultaneous support
|
|
# of 'long long' and 'unsigned long long'. We don't want to say that
|
|
# 'long long' is available if 'unsigned long long' is not, or vice versa,
|
|
# because too many programs rely on the symmetry between signed and unsigned
|
|
# integer types (excluding 'bool').
|
|
AC_DEFUN([_AC_TYPE_LONG_LONG_SNIPPET],
|
|
[
|
|
AC_LANG_PROGRAM(
|
|
[[/* For now, do not test the preprocessor; as of 2007 there are too many
|
|
implementations with broken preprocessors. Perhaps this can
|
|
be revisited in 2012. In the meantime, code should not expect
|
|
#if to work with literals wider than 32 bits. */
|
|
/* Test literals. */
|
|
long long int ll = 9223372036854775807ll;
|
|
long long int nll = -9223372036854775807LL;
|
|
unsigned long long int ull = 18446744073709551615ULL;
|
|
/* Test constant expressions. */
|
|
typedef int a[((-9223372036854775807LL < 0 && 0 < 9223372036854775807ll)
|
|
? 1 : -1)];
|
|
typedef int b[(18446744073709551615ULL <= (unsigned long long int) -1
|
|
? 1 : -1)];
|
|
int i = 63;]],
|
|
[[/* Test availability of runtime routines for shift and division. */
|
|
long long int llmax = 9223372036854775807ll;
|
|
unsigned long long int ullmax = 18446744073709551615ull;
|
|
return ((ll << 63) | (ll >> 63) | (ll < i) | (ll > i)
|
|
| (llmax / ll) | (llmax % ll)
|
|
| (ull << 63) | (ull >> 63) | (ull << i) | (ull >> i)
|
|
| (ullmax / ull) | (ullmax % ull));]])
|
|
])
|